🆕get

Gibt den Wert eines bestimmten Feldes zurück

Diese Funktion gibt den Wert eines Feldes zurück. Mit get können Sie auf Felder über ihren Namen oder ihre ID zugreifen, um Daten für Skripts und Berechnungen zu ermitteln.

Syntax

get(nid, string)

Rückgabewert

text

number

boolean

void

Vorteile von get

• Einfache Handhabung: Unabhängig von der Art der Daten können Sie diese einheitlich aus den Feldern abrufen, was die Arbeit deutlich vereinfacht.

• Integration: Die Funktion get lässt sich nahtlos mit anderen Funktionen wie set kombinieren, sodass Sie Daten in Ihren Skripten dynamisch aktualisieren und verwalten können.

• Mehr Flexibilität: Mit der Funktion get können Sie Daten entweder anhand des Namens oder der ID eines Feldes abrufen. Das erleichtert den Umgang mit unterschiedlichen Benennungen und Datenbankstrukturen.

Durch die Verwendung der Funktion get wird der Datenzugriff in Ninox vereinfacht, was eine effizientere Verwaltung und eine problemlose Integration mit anderen Funktionen ermöglicht.

Beispiele

Hier sind ein paar einfache Beispiele, die zeigen, wie die Funktion mit unterschiedlichen Eingaben funktioniert.

get(this, "Name")

Rückgabewert: Vania

get(this, "Ja/Nein")

Rückgabewert: true

get(this, "B")

Rückgabewert: 42

get(this, "")

Rückgabewert: void

Herkömmliche Methode

In einem typischen Szenario sind die Feldnamen in Checklisten-Formularen oft nummeriert. Zum Beispiel:

• Objekt Name 1, Wert 1, Datum 1

• Objekt Name 2, Wert 2, Datum 2

• Objekt Name 3, Wert 3, Datum 3

Zum Sammeln all dieser Daten und zum Ablegen in einer Untertabelle könnten Sie normalerweise Folgendes verwenden:

let me := this;
let myReport := Report;
let newSubRecord := (create Subtable);
newSubRecord.(
	Report := myReport;
	'Objekt Name' := me.'Objekt Name 1';
	Datum := me.'Datum 1';
	Wert := me.'Wert 1'
);
newSubRecord := (create Subtable);
newSubRecord.(
	Report := myReport;
	'Objekt Name' := me.'Objekt Name 2';
	Datum := me.'Datum 2';
	Wert := me.'Wert 2'
);
newSubRecord := (create Subtable);
newSubRecord.(
	Report := myReport;
	'Objekt Name' := me.'Objekt Name 3';
	Datum := me.'Datum 3';
	Wert := me.'Wert 3'
)

Bei der herkömmlichen Methode müssen Sie jedes Objekt einzeln angeben. Wenn Sie viele Objekte haben, wird Ihr Skript dadurch länger und komplizierter. Mit den Funktionen get und set bleibt Ihr Skript jedoch übersichtlich und einfach zu handhaben, egal wie viele Objekte es gibt.

Dynamische Datenerfassung mit get und set

Die Funktionen get und set vereinfachen diesen Prozess. get zieht den Wert aus dem Hauptdatensatz, indem es den Feldnamen dynamisch auf der Grundlage des aktuellen Index erstellt. Mit set wird dieser Wert dann in das entsprechende Feld im neuen Datensatz der Untertabelle gezogen. So können Sie sie verwenden:

let me := this;
let nameSpace := ["Objekt Name", "Datum", "Wert"];
let myReport := Report;
for i in range(3) do
	let newSubRecord := (create Subtable);
	newSubRecord.(Report := me.Report);
	for name in nameSpace do
		set(newSubRecord, name, get(me, name + " " + (i + 1)))
	end
end

Siehe auch

set, aktualisiert den Wert eines bestimmten Feldes.