> For the complete documentation index, see [llms.txt](https://docs.ninox.com/llms.txt). Markdown versions of documentation pages are available by appending `.md` to page URLs; this page is available as [Markdown](https://docs.ninox.com/ninox-scripting/de/automate-your-workflows/work-with-functions/system-flow-control-and-ai.md).

# System, Ablaufsteuerung und Ninox AI

Lerne, wie du Skripte pausierst und den Ausführungskontext der App prüfst.

Funktionen für System und Ablaufsteuerung helfen dir, Timing und umgebungsspezifisches Verhalten zu steuern. Du kannst ein Skript pausieren, Rohwerte prüfen und den App-Kontext erkennen.

In diesem Kapitel lernst du, wie du:

* Timing in einem laufenden Skript steuerst.
* die aktuelle App-Umgebung und den Datenbankstatus prüfst.

<table><thead><tr><th width="233.96484375">Funktion (A-Z)</th><th>Aufgabe</th></tr></thead><tbody><tr><td><code>eval()</code></td><td>Führt einen Text als Skript aus</td></tr><tr><td><code>generateObject()</code></td><td>Ruft JSON-Objektdaten mit Ninox AI ab</td></tr><tr><td><code>generateText()</code></td><td>Ruft Textdaten mit Ninox AI ab</td></tr><tr><td><code>ninoxApp()</code></td><td>Gibt den aktuellen Client- oder App-Kontext zurück</td></tr><tr><td><code>raw()</code></td><td>Gibt die interne Textdarstellung zurück</td></tr><tr><td><code>sleep()</code></td><td>Pausiert ein Skript kurz</td></tr></tbody></table>

## Timing und Ausführungsreihenfolge steuern

Nutze diese Funktionen, wenn eine Aktion erst nach einer anderen ausgeführt werden soll.

### Ein Skript kurz pausieren <a href="#pause-a-script-with-sleep" id="pause-a-script-with-sleep"></a>

Nutze `sleep()`, damit Ninox eine angegebene Anzahl an Millisekunden wartet, bevor das Skript weiterläuft.

Nutze es, wenn du:

* eine kurze Verzögerung vor einer Folgeaktion einbauen willst.
* Timing-Probleme in einem UI-Ablauf vermeiden willst.
* kurz warten willst, bis sich ein anderer Prozess stabilisiert.
* einen Hinweis oder eine Warnung anzeigen willst, bevor der nächste Schritt läuft.

`sleep(number)`

* `number` die Verzögerung in Millisekunden

`sleep()` gibt keinen Wert zurück.

#### Schauen wir uns einige Beispiele an:

```ninox
sleep(2000)
```

Pausiert das Skript für 2 Sekunden.

Tipps:

* Halte Verzögerungen so kurz wie möglich.
* Nutze eine Verzögerung nur, wenn der Ablauf sie wirklich braucht.

## Rohwerte und Bereichsgrenzen prüfen

Nutze diese Funktionen, wenn du den zugrunde liegenden Wert oder die Startgrenze eines Dauer- oder Bereichskontexts brauchst.

### Den Rohwert prüfen <a href="#inspect-the-raw-value" id="inspect-the-raw-value"></a>

Nutze `raw()`, um die interne rohe Textdarstellung eines Werts zurückzugeben.

Nutze es, wenn du:

* formatierten Text in seine rohe Textform umwandeln willst.
* den internen Wert hinter einem Farbfeld lesen willst.
* formatierte Inhalte in Dialogen oder E-Mails wiederverwenden willst.
* die Rohform mit der angezeigten Form vergleichen willst.

`raw(any)`

* `any` der Wert, den du in Rohform zurückgeben willst

`raw()` gibt einen String zurück.

#### Schauen wir uns einige Beispiele an:

```ninox
raw('My sample text')
```

Gibt den Inhalt eines formatierten Textwerts als unformatierten Text mit HTML-Tags zurück.

```ninox
dialog("Hello", raw('Dialog text'), ["Yes", "No"])
```

Zeigt einen Dialog mit dem Inhalt des formatierten Textfelds `Dialog text`.

```ninox
raw(Color)
```

Gibt den internen Farbwert zurück, zum Beispiel `#EC87E2`.

Tipps:

* Nutze `raw()`, wenn du die interne Textdarstellung des Systems brauchst.
* Das ist nützlich für formatierte Textfelder, Dialoge und E-Mails.
* Du kannst das Ergebnis später wieder mit `html()` formatieren.

### Text als Logik ausführen und Daten mit `eval()` prüfen

Nutze `eval()`, um Text als Ninox Skript auszuführen.

Damit erstellst du dynamische Ausdrücke. Verwende zum Beispiel Namen von Tabellen, Feldern und Variablen, die sich zur Laufzeit ändern.

`eval(string, nid)`

* `string` Text mit Berechnungen oder einem Ninox Skript
* `nid` Datensatz, auf den das Skript angewendet wird

#### Schauen wir uns einige Beispiele an:

```
eval(manuelle_formel, this) 
```

Gibt `20` zurück, wenn das Feld "Manuelle Formel" im aktuellen Datensatz `14 + 6 \* 0.5 \* 2` enthält.

<pre><code><strong>let myTabelle := "rechnungen"; 
</strong>eval("sum((select " + myTabelle + ").betrag)", this)
</code></pre>

Gibt die Summe aller Beträge in der Tabelle "Rechnungen" zurück.

```
let myText := "alert(""Das ist ein Test."")"; 
eval(myText, this)
```

Zeigt eine Meldung mit dem Text "Das ist ein Test." an.

```
let myFeld := "vollstaendiger_name"
eval(myFeld, this) 
```

Gibt den Wert "Toni Kim" aus dem Feld "Vollständiger Name" zurück. Bei einem Auswahlfeld gibt die Funktion den Index des Werts zurück.

```
let myAuswahl := "Auswahlfeld";
eval("text(" + myAuswahl + ")", this)
```

Gibt den Textwert der gewählten Option eines Auswahlfelds zurück.

```
let myTabelle := "kontakte";
let myFeld := text(Auswahlfeld);
let myAktuellerName := eval("text(" + myFeld + ")", this);
cnt(eval("select " + myTabelle + " where " + myFeld + " = " + myAktuellerName, this))
```

Gibt die Anzahl der Datensätze in der Tabelle "Kontakte" zurück, deren Feld "Vollständiger Name" dem gewählten Feldwert im aktuellen Datensatz entspricht. Nutze diesen Ansatz für dynamische Duplikatsuchen, wenn `myFeld` aus einem Auswahlfeld stammt.

## App-Kontext und Datenbankstatus erkennen

Nutze diese Funktionen, wenn dein Skript auf den aktuellen Client oder den Schutzstatus der Datenbank reagieren soll.

### Mit `ninoxApp()` die aktuelle App erkennen <a href="#inspect-the-app-context" id="inspect-the-app-context"></a>

Nutze `ninoxApp()`, um zu prüfen, wo dein Skript ausgeführt wird.

Nutze es, wenn du:

* Verhalten je nach Client anpassen willst.
* client-spezifische Workflows diagnostizieren willst.

`ninoxApp()`

`ninoxApp()` gibt einen String zurück, der die aktuelle Umgebung kennzeichnet.

Mögliche Rückgabewerte sind:

* `client`
* `server`

#### Schauen wir uns einige Beispiele an:

```ninox
ninoxApp() = "client"
```

Gibt einen String zurück, der zeigt, wo das Skript läuft.

Tipps:

* Nutze `ninoxApp()`, um zu prüfen, ob UI-Funktionen ausgeführt werden können. Das ist nicht der Fall, wenn das Ergebnis `server` ist.

## Mit `generateObject()` und `generateText()` Aufgaben mit Ninox AI ausführen

Nutze diese beiden Funktionen, um Daten und Anweisungen an Ninox AI zu senden und Text oder ein JSON-Objekt zu erhalten. Nutze sie, um Texte zu klassifizieren, Werte zu extrahieren oder Felder automatisch auszufüllen.

`generateObject(prompt, format)` gibt ein JSON-Objekt mit den von `format` angeforderten Feldern zurück.\
`generateObject(prompt, format, model)`\
`generateText(prompt)` gibt Text zurück.\
`generateText(prompt, model)`

* `prompt` ein Textwert oder ein Array aus Texten. Es enthält die Daten, die Ninox AI prüfen soll, sowie den Prompt für Ninox AI.
* `format` JSON-Werte, die die zurückgegebenen Felder und ihre Typen definieren: `"string"`, `"number"`, `"boolean"`, `"date"` oder eine Liste von Textwerten, wenn Ninox AI eine Option wählen soll. Übergebe sie in geschwungenen Klammern an die Funktion.
* `model` ein JSON-Wert, um ein AI-Modell auszuwählen: `"haiku"` (Standard), `"sonnet"`, `"opus"` oder `"luna"`. Übergebe ihn in geschwungenen Klammern.

{% hint style="info" %}
Weitere Details zu den von Ninox AI verwendeten KI-Modellen findest du [hier](https://docs.ninox.com/builder-hub/ninox-ai/ninox-ai.md).
{% endhint %}

Wenn du Ninox-Felder verwendest, werden ihre Rohwerte übernommen. Bei einem Auswahlfeld ist das beispielsweise die Options-ID statt der Bezeichnung. Nutze die Funktion `text()`, um stattdessen den Textwert zu erhalten.

Lies die Felder des Ergebnisses mit `r.field`, `item(r, "field")` oder `for key, value in r do … end`.

Ein Datum wird als Text im Format `YYYY-MM-DD` zurückgegeben. Nutze `date()`, um es in einen Datumswert umzuwandeln.

Beachte die folgenden Limits:

* `format`-Felder: maximal 20. Verwende nach Möglichkeit 1-7.
* Optionen pro Liste: 2-50. Verwende nach Möglichkeit bis zu 10.
* Feldnamen: nur Buchstaben, Ziffern und `_`. Beginne mit einem Buchstaben. `error` ist reserviert.
* Größe von `prompt`: maximal 20.000 Zeichen
* Timeout: 25 Sekunden
* AI-Calls pro Skriptausführung: maximal 50
* 4 gleichzeitige Calls pro Arbeitsbereich

{% hint style="info" %}
Verwende `generateObject()` und `generateText()` in Triggern innerhalb von `do as deferred`. Sie sind nicht in Logikfeldern oder in `do as transaction` verfügbar.
{% endhint %}

#### Schauen wir uns einige Beispiele an:

```ninox
let r := generateObject(
    [nachricht, "Wähle eine Kategorie und Priorität."], {
    kategorie: ["Bug", "Frage"],
    prioritaet: ["Hoch", "Mittel", "Niedrig"]
    });
if r.error then
    alert(r.error)
else
    kategorie := r.kategorie;
    prioritaet := r.prioritaet
end
```

Klassifiziert ein Support-Ticket und füllt die Felder für Kategorie und Priorität aus.

```ninox
let r := generateObject(
    text(email_text) + " Ermittle die Anzahl der Lizenzen und das Startdatum.", {
    lizenzen: "number",
    startDatum: "date"}, {
    model: "sonnet"});
if not r.error then
    lizenzen := r.lizenzen;
    start_datum := date(r.startDatum);
    gesamtpreis := r.lizenzen * preis_pro_lizenz
end
```

Extrahiert eine Zahl und ein Datum aus einer E-Mail. Die zurückgegebene Zahl kannst du in Berechnungen verwenden.

```ninox
let t := generateText(["Betr: " + email_betreff + "Nachr: " + text(email_inhalt), 
                       "Fasse die Anfrage zusammen!"]);
if not t.error then
    alert(t)
end
```

Gibt eine Zusammenfassung der E-Mail, unter Berücksichtigung von Betreff und Nachricht, in einer Pop-up-Nachricht aus.

### Mehrere Datensätze verarbeiten

Du kannst die Funktionen einmal pro Datensatz oder einmal für eine Gruppe von Datensätzen aufrufen. Wähle den Ansatz anhand des benötigten Ergebnisses.

Nutze einen AI-Call pro Datensatz, wenn du für jeden Datensatz ein Feld ausfüllen musst. Dieses Beispiel klassifiziert jeden Datensatz in der Tabelle "Tickets":

```ninox
for t in select Tickets do
    let r := generateObject([t.nachricht, "Klassifiziere das Ticket."], {
        kategorie: ["Bug", "Frage", "Funktionsvorschlag"]}
    });
    if not r.error then
        t.kategorie := r.kategorie
    end
end
```

Fünf Datensätze führen zu fünf AI-Calls. Jeder Datensatz erhält eine eigene Kategorie.

Nutze einen AI-Call für alle Datensätze, wenn du eine Übersicht oder einen Bericht für mehrere Datensätze benötigst. Dieses Beispiel sendet alle Titel und Nachrichten der Tickets in einem AI-Call:

```ninox
let myDaten := for t in select Tickets do
   "Titel: " + t.titel + ", Anfrage: " + t.anfrage
end;
let r := generateText(myDaten + " Was ist das häufigste Problem in den Anfragen?", {
                        model: "opus"});
if not r.error then
    alert(r)
end
```

Fünf Datensätze führen zu einem AI-Call. Dieser Ansatz ist schneller und benötigt weniger AI-Credits.

{% hint style="info" %}
Rufe die Funktion einmal pro Datensatz auf, wenn jeder Datensatz ein eigenes Ergebnis benötigt. Dieser Ansatz füllt Felder, aber fünf Datensätze erfordern fünf AI-Calls.\
\
Rufe die Funktion einmal für alle Datensätze auf, wenn du ein gemeinsames Ergebnis benötigst. Dieser Ansatz eignet sich für Übersichten und Berichte. Fünf Datensätze erfordern einen AI-Call.
{% endhint %}

Tipps:

* Jeder AI-Call verbraucht AI-Credits.
* Sende nur notwendige Daten an Ninox AI.
* Inhalte von Prompts, Nachrichten oder Antworten werden nicht protokolliert.
* Das Ergebnis enthält die in `format` definierten Felder. Unbekannte Werte sind `null`.
* Bei einem Fehler geben beide Funktionen `{error: "message"}` zurück. Prüfe `r.error`, bevor du das Ergebnis verwendest.


---

# Agent Instructions
This documentation is published with GitBook. GitBook is the documentation platform designed so that both humans and AI agents can read, navigate, and reason over technical content effectively. Learn more at gitbook.com.

## Querying This Documentation
If you need additional information that is not directly available in this page, you can query the documentation by asking a question.

Perform an HTTP GET request on the following URL with the `ask` and `goal` query parameters:

```
GET https://docs.ninox.com/ninox-scripting/de/automate-your-workflows/work-with-functions/system-flow-control-and-ai.md?ask=<question>&goal=<user_goal>
```

`ask` is the immediate question: it should be specific, self-contained, and written in natural language.
`goal` is what the user is ultimately trying to achieve, the reason they need the answer. Sharing it helps GitBook give you a better, more relevant answer. A goal is most helpful when it describes the outcome the user wants rather than restating the question. For example, with `ask=how do I create an API token`, a goal like `automate deployments from our CI pipeline` lets GitBook tailor the answer to that use case.

The response will contain a direct answer to the question and relevant excerpts and sources from the documentation.

Use this mechanism when the answer is not explicitly present in the current page, you need clarification or additional context, or you want to retrieve related documentation sections.
